#!/usr/bin/perl -w
#-----------------------------------------------------------------------------
#
#  Copyright (C) 2000 Ryan C. Gordon (icculus@linuxgames.com)
#
#  This program is free software; you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation; either version 2 of the License, or
#  (at your option) any later version.
#
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with this program; if not, write to the Free Software
#  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
#
#-----------------------------------------------------------------------------

#-----------------------------------------------------------------------------
# Revision history:
#  1.0.0 : First release
#  1.0.2 : Minor bugfixes.
#  1.1.0 : Prints version in <title>, more customizable, optionally allows
#           fingering to arbitrary sites for use as a web interface to finger,
#           supports VirtualHost sites, better error output.
#  1.1.1 : Highlights URLs and email addresses.
#  1.2.0 : Changed email address. Moved script name to $script_link.
#           Reads [title], [url], and [img] tags.
#  1.2.1 : [center] and [font] tags added.
#  1.3.0 : (Yes, I went up two minors in one day.) Plain text output from
#           the command line.
#  1.3.1 : Added bold, italics, and underlines ([b][u][i][/i][/u][/b])
#           Text output gets the witty remark, etc, too.
#  1.3.2 : Added "?format=n" argument to the web interface, and fixed a
#           formatting bug with the [center] tag in Opera.
#  1.3.3 : [link] tags spit out URL in non HTML formatted version. Handles
#           newlines in [center] tags for Opera. Fixed bug where HTML
#           formatting was enabled in the regular finger interface.
#  1.3.4 : Bugfixes to the "&" -> "&amp;" substitution and the URL
#           highlighter. Added almost useless debugging facility.
#-----------------------------------------------------------------------------

# TODO: Let [img] tags nest inside [link] tags.
# TODO: Make [center] tags attempt to format plain text.

use strict;

# Version of IcculusFinger. Change this if you are forking the code.
my $version = "v1.3.4";


# This is the default title for the webpage. The user can override it with
#  the [title] tag in their .plan file.
my $title = "IcculusFinger $version";


# Location where the server can find the finger client it will be using
#  to get information. This string is executed and what it writes to stdout
#  is read in by this script.
my $fingerprog = "/usr/local/bin/afinger --portname=fingertags";


# Uncomment this to always do finger requests to the same host.
# Define which host the finger request goes to. If you don't define $host,
#  then users may finger any system on the internet by specifying a hostname:
#  user=dimwit@doofus.com, for example. Not setting $host at all like that
#  could leave a mild exploit available.
# This is ignored if run from the command line.
#my $host = undef;   # Makes this script work as a web interface to finger.
#my $host = "icculus.org";  # limit queries to users@icculus.org
my $host = $ENV{SERVER_NAME}; #  This is good for VirtualHost setups.


# This is the URL to where the script can be obtained. Feel free to change
#  it if you like. Leave it undef'd to not supply a link at all in the
#  final HTML output.
#my $scripturl = undef;
#my $scripturl = "/misc/finger.pl";
my $scripturl = "http://icculus.org/IcculusFinger/";


# This is printed after the credits at the bottom. Change it to whatever you
#  like. Do not use HTML. You can specify an empty string (""), but undef
#  doesn't fly here.
my $wittyremark = "Stick it in the camel and go.";

# you can screw up your output with this, if you like.
my $debugging = 0;

#-----------------------------------------------------------------------------#
#     The rest is probably okay without you laying yer dirty mits on it.      #
#-----------------------------------------------------------------------------#

my $script_link = (defined $scripturl) ?
                     "<a href=\"$scripturl\">IcculusFinger $version</a>" :
                     "IcculusFinger $version" ;

my $is_web_interface = 0;
my $do_html_formatting = 0;
my $browser = "";
my $user;

sub output_start {

    return if not $is_web_interface;

print <<__EOF__;
Content-type: text/html


<html>
  <head>
    <title> $title </title>
  </head>

  <body>

__EOF__

}


sub output_ending {

    # TODO: Make that ------ line fit the length of the strings.
    if (not $is_web_interface) {
        print "-------------------------------------------------------------------------\r\n";
        print "IcculusFinger $version by Ryan C. Gordon (icculus\@clutteredmind.org)\r\n";
        print "$wittyremark\r\n\r\n";
        return;
    }

print <<__EOF__;

    <hr>
    <center>
      <font size="-3">
        $script_link was written by
        <a href="mailto:icculus\@clutteredmind.org">Ryan C. Gordon</a>.
        <br><i>$wittyremark</i>
      </font>
    </center>

  </body>
</html>

__EOF__

}




# Mainline.

$host =~ tr/A-Z/a-z/ if defined $host;

if ((defined $ENV{GATEWAY_INTERFACE}) and ($ENV{GATEWAY_INTERFACE} ne "")) {
    $is_web_interface = 1;
    $do_html_formatting = 1;

    if ((defined $ENV{HTTP_USER_AGENT}) and ($ENV{HTTP_USER_AGENT} ne "")) {
        $browser = $ENV{HTTP_USER_AGENT};
    }

    my $QueryString = $ENV{QUERY_STRING};
    if ($QueryString =~ /user=(.*)/) {
        $user = $1;
        $user =~ s/&.*//;
        $user =~ tr/A-Z/a-z/;
    }

    if ($QueryString =~ /format=(.*)/) {
        $do_html_formatting = $1;
        $do_html_formatting =~ s/&.*//;
        $do_html_formatting =~ tr/A-Z/a-z/;
    }

} else {
    $user = shift;
    if (not defined $user) {
        print("USAGE: $0 <username[\@hostname.dom]>\n");
        exit 42;
    }
    $user = "$user\@localhost" if (not $user =~ /\@/);
    $is_web_interface = 0;
    $do_html_formatting = 0;
}

my $requested_host = undef;
if ((defined $user) && ($user =~ s/\@(.*)//)) {
    $requested_host = $1;
    $requested_host =~ tr/A-Z/a-z/;
}

my $errormsg = undef;
if (not defined $user) {
    $errormsg = "No user specified.";
} elsif ((not defined $host) and (not defined $requested_host)) {
    $errormsg = "No host specified.";
} elsif ((defined $host) and (defined $requested_host)) {
    if (($is_web_interface) and ($host ne $requested_host)) {
        $errormsg = "You aren't permitted to specify a hostname, just a user.";
    }
} elsif (length($user) > 20) {
    # The 20 char limit is just for safety against potential buffer overflows
    #  in finger servers, but it's more or less arbitrary.
    # !!! TODO FIXME: Check for bogus characters in username/host.
    $errormsg = "Bogus user specified.";
}

if (defined $errormsg) {
    output_start();
    print "    <center><h1>" if $is_web_interface;
    print "$errormsg";
    print "</h1></center>" if $is_web_interface;
    print "\n";
} else {
    if (not defined $host) {
        $host = $requested_host;
    }

    if ($debugging) {
        print("fingering $user at $host ...\n");
        print("HTML formatting: $do_html_formatting ...\n");
        print("Is web interface: $is_web_interface ...\n");
    }

    if (not open(FINGER, "$fingerprog $user\@$host |")) {
        output_start();
        print("    <center><h1>Couldn't run finger program: $!.</h1></center>\n\n");
    } else {
        my $output_text = "";
        while (<FINGER>) {
            $output_text = $output_text . $_;
        }
        close(FINGER);

        # Change [title][/title] tags.
        while ($output_text =~ s/\[title\](.*?)\[\/title\]//is) {
            $title = $1;
        }

        if ($is_web_interface) {
            # HTMLify some common characters...
            1 while ($output_text =~ s/\&(?!amp)/&amp;/s);
            1 while ($output_text =~ s/</&lt;/s);
            1 while ($output_text =~ s/>/&gt;/s);
        }

        # Change [b][/b] tags.
        if ($do_html_formatting) {
            1 while ($output_text =~ s/\[b](.*?)\[\/b\]/<b>$1<\/b>/is);
        } else {
            1 while ($output_text =~ s/\[b](.*?)\[\/b\]/$1/is);
        }

        # Change [i][/i] tags.
        if ($do_html_formatting) {
            1 while ($output_text =~ s/\[i](.*?)\[\/i\]/<i>$1<\/i>/is);
        } else {
            1 while ($output_text =~ s/\[i](.*?)\[\/i\]/$1/is);
        }

        # Change [u][/u] tags.
        if ($do_html_formatting) {
            1 while ($output_text =~ s/\[u](.*?)\[\/u\]/<u>$1<\/u>/is);
        } else {
            1 while ($output_text =~ s/\[u](.*?)\[\/u\]/$1/is);
        }

        # Change [center][/center] tags.
        if ($do_html_formatting) {
            if ($browser =~ /Opera/) {
                while ($output_text =~ /\[center](.*?)\[\/center\]/is) {
                    my $buf = $1;
                    1 while ($buf =~ s/\n/<br>/s);
                    $output_text =~ s/\[center](.*?)\[\/center\]/<\/pre><center><code>$buf<\/code><\/center><pre>/is;
                }
            } else {
                1 while ($output_text =~ s/\[center](.*?)\[\/center\]/<center>$1<\/center>/is);
            }
        } else {
            1 while ($output_text =~ s/\[center](.*?)\[\/center\]/$1/is);
        }

        # Change [font][/font] tags.
        if ($do_html_formatting) {
            1 while ($output_text =~ s/\[font (.*?)](.*?)\[\/font\]/<font $1>$2<\/font>/is);
        } else {
            1 while ($output_text =~ s/\[font (.*?)](.*?)\[\/font\]/$2/is);
        }

        # Change [link][/link] tags.
        if ($do_html_formatting) {
            1 while ($output_text =~ s/\[link=\"(.*?)\"\](.*?)\[\/link\]/<a href=\"$1\">$2<\/a>/is);
        } else {
            1 while ($output_text =~ s/\[link=\"(.*?)\"\](.*?)\[\/link\]/$2 \[$1\]/is);
        }

        # Change [img][/img] tags.
        if ($do_html_formatting) {
            1 while ($output_text =~ s/\[img=\"(.*?)\"\](.*?)\[\/img\]/<img src=\"$1\" alt=\"$2\">/is);
        } else {
            1 while ($output_text =~ s/\[img=\"(.*?)\"\](.*?)\[\/img\]/$2/is);
        }

        if ($do_html_formatting) {
            # try to make URLs into hyperlinks in the HTML output.
            1 while ($output_text =~ s/(?<!href=")(?<!src=")(?<!">)\b([a-zA-Z]+?:\/\/[\S]+)/<a href="$1">$1<\/a>/);

            # try to make email addresses into hyperlinks in the HTML output.
            1 while ($output_text =~ s/\b(?<!href="mailto:)(?<!">)\b([\w\.]+?\@[\w\.]+)/<a href=\"mailto:$1\">$1<\/a>/);

            # HTMLify newlines.
            #1 while ($output_text =~ s/\r//s);
            #1 while ($output_text =~ s/(?<!<br>)\n/<br>\n/s);
        }

        output_start();

        if ($is_web_interface) {
            print("    <center><h1>Finger info for $user\@$host...</h1></center>\n");
            #print("    <hr><code>\n\n");
            print("    <hr>\n\n<pre>\n\n");
            print("$output_text");
            #print("</code>\n\n");
            print("\n</pre>\n");
        } else {
            print("$title\n\n");
            print("$output_text\n");
        }
    }
}

output_ending();

exit 0;

# end of finger.pl ...